m4_define([tcc_VERSION], m4_normalize(m4_include([VERSION])))
m4_append([tcc_VERSION], [-stupidos])

AC_INIT([tcc], tcc_VERSION)

AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([foreign subdir-objects -Werror -Wall])

AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([
	Makefile
	libtcc/Makefile
	tcc/Makefile
	libtcc1/Makefile])

AC_LANG([C])
AC_PROG_CC
AC_PROG_CPP
AC_PROG_CC_C_O
AC_PROG_RANLIB
AM_PROG_AR
AM_PROG_AS

AC_CHECK_INCLUDES_DEFAULT
AC_C_CONST
AC_C_INLINE
AC_C_BIGENDIAN
AC_C_CHAR_UNSIGNED

AC_CHECK_HEADERS([
	libgen.h
	sys/queue.h
])

AC_ARG_ENABLE([memory_debug],
	[AS_HELP_STRING([--enable-memory-debug=<level>], [enable memory debuging with <level> (1, 2, 3)])])

AS_CASE([$enable_memory_debug],
	[[[1-3]]], [AC_DEFINE_UNQUOTED([TCC_MEMORY_DEBUG], [$enable_memory_debug], [enable memory debug])],
	[*yes*], [AC_DEFINE([TCC_MEMORY_DEBUG], [1], [enable memory debug])])

AC_ARG_ENABLE([asm_debug],
	[AS_HELP_STRING([--enable-asm-debug], [enable asm debug])])

AS_IF([test "x$enable_asm_debug" = "xyes"],
	[AC_DEFINE([ASM_DEBUG], [1], [enable asm debug])])

AC_ARG_ENABLE([inc_debug],
	[AS_HELP_STRING([--enable-inc-debug], [enable include file debug])])

AS_IF([test "x$enable_inc_debug" = "xyes"],
	[AC_DEFINE([INC_DEBUG], [1], [enable include file debug])])

AC_ARG_ENABLE([pp_debug],
	[AS_HELP_STRING([--enable-pp-debug], [enable preprocessor debug])])

AS_IF([test "x$enable_pp_debug" = "xyes"],
	[AC_DEFINE([PP_DEBUG], [1], [enable preprocessor debug])])

AC_ARG_ENABLE([parser_debug],
	[AS_HELP_STRING([--enable-parser-debug], [enable parser debug])])

AS_IF([test "x$enable_parser_debug" = "xyes"],
	[AC_DEFINE([PARSE_DEBUG], [1], [enable parser debug])])

AC_OUTPUT