AC_INIT([65∞2], [1.0],
		[https://git.cute.engineering/d0p1/65oo2/issues],
		[65oo2],
		[https://git.cute.engineering/d0p1/65oo2])

AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign subdir-objects])

AC_CONFIG_HEADERS([config.h])

case "$host_os" in
	cygwin*|mingw*)
		OS_TYPE=windows;;
	*)
		OS_TYPE=unknown;;
esac
AM_CONDITIONAL([OS_WINDOWS], test "$OS_TYPE" = "windows")

AC_LANG(C)
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_RANLIB
AM_PROG_AS
AM_PROG_AR
AM_PROG_CC_C_O
PKG_PROG_PKG_CONFIG
AC_CHECK_TOOLS(WINDRES, [windres], :)

PKG_CHECK_MODULES([SDL2], [sdl2])
SDL2_LIBS=${SDL2_LIBS/-mwindows/}

AC_ARG_ENABLE([ata-vga],
	[AS_HELP_STRING([--enable-ata-vga], [enable VGA (default=yes)])],
	[WANT_ATA_VGA=$enableval], [WANT_ATA_VGA=yes])
AC_ARG_ENABLE([ata-ethernet],
	[AS_HELP_STRING([--enable-ata-ethernet], [enable ethernet device (default=yes)])],
	[WANT_ATA_ETHERNET=$enableval], [WANT_ATA_ETHERNET=yes])

AC_ARG_ENABLE(mmu,
	[AS_HELP_STRING([--enable-mmu], [enable MMU (default=yes)])],
	[WANT_MMU=$enableval], [WANT_MMU=yes])
AC_ARG_ENABLE(jit,
	[AS_HELP_STRING([--enable-jit], [enable JIT compiler (default=no)])],
	[WANT_JIT=$enableval], [WANT_JIT=no])

AC_CHECK_INCLUDES_DEFAULT
AC_CHECK_HEADERS([libgen.h])
AC_C_CONST

AM_CONDITIONAL([USE_ATA_VGA], test "$WANT_ATA_VGA" = "yes")
if test "$WANT_ATA_VGA" = "yes"; then
   AC_DEFINE([ATA_VGA], [1], [Enable VGA device])
fi

AM_CONDITIONAL([USE_ATA_ETHERNET], test "$WANT_ATA_ETHERNET" = "yes")
if test "$WANT_ATA_ETHERNET" = "yes"; then
   AC_DEFINE([ATA_ETERNET], [1], [Enable Ethernet device])
fi

AM_CONDITIONAL([USE_MMU], test "$WANT_MMU" = "yes")
AM_CONDITIONAL([USE_JIT], test "$WANT_JIT" = "yes")

AC_CONFIG_FILES([
        Makefile
        lib/Makefile
        disas/Makefile
        vm/Makefile])
AC_OUTPUT